/*
Versalab M3 Grinder Controller (based on ATtiny85)
Ver 1.1

For use with optional hopper (required).

Operation:
1. Hopper slide activates grind (using microswitch)
2. Motor current is monitored to sense when grinding is complete
3. Optional eggdrop function clears the grinder funnel by pulsing the motor
4. System sleeps waiting for the next trigger

See [url=/grinders/automating-versalab-m3-t34196.html]Automating the Versalab M3[/url] for more information, wiring diagrams and important safety notices.
*/

// We need these for sleep and power management
#include <avr/power.h>
#include <avr/sleep.h>

  /*
  Trinket Pin Assignments:
  USB+ - +5VDC from Power Supply
  GND  - Ground from Power Supply
  #3, RST, Bat+ - N/C
  #4 - ACS712 Output (Analog A2 input)
  #2 - Switch to trigger power
  #0 - Relay module to motor driver - inverse logic
  5V   - Power to ACS712 Module and Relay output module 
  */

// Settings  
#define LED 01 // Onboard LED PWM Control (LED shows current through motor)
#define MOTOR 00 // Pin #0 for Relay Output Module
#define SW 02 // Pin #2 for interrupt trigger input
#define THRESHOLD 400 // Versalab Grinder motor takes about 330mA without beans. So 400mA will be our threshold - Assumption: Grinding current is in the 500-1300mA
#define DELAY_ON 3 // delay in seconds before motor stops
#define DELAY_OFF 2 // delay in seconds before motor stops
#define EGG_DROPS 2 // # of times eggs are dropped after a grind (set to 0 to disable)
#define EGG_DROP_TIME 750 // Off time for an egg to drop in mSec

// ACS712x20A current sensor module input on the pin labelled #4 which is actually A/D input pin #2 (confusing a bit but refer to ATTiny85 datasheet) 
const int CurrentAnalogPin = 2;         // associated analog pin number to use with analogRead()
const int adc_zero = 509;// relative digital zero of the arudino input from ACS712 (could make this a variable and auto-adjust it)
const int current_factor = 50000 / 1023 ; // ACS712 EC20A: 50,000 mA to 5V ratio for 1023 count ADC

// RMS calculation timing from http://forum.arduino.cc/index.php?topic=179541.15
const unsigned long sampleTime = 100000UL;                           // sample over 100ms, it is an exact number of cycles for both 50Hz and 60Hz mains
const unsigned long numSamples = 250UL;                               // choose the number of samples to divide sampleTime exactly, but low enough for the ADC to keep up
const unsigned long sampleInterval = sampleTime/numSamples;  // the sampling interval, must be longer than then ADC conversion time

// Various counters
int egg_counter = 0;
volatile int delayLeft = 0;       // initialize state to 'off' (when delayLeft=0 motor is off) (Volatile for interrupt)
unsigned long last_second; // Used for timer delay

void setup() {
  pinMode(LED, OUTPUT);
  pinMode(SW, INPUT);
  digitalWrite(SW, HIGH); // Pullup resistor
  pinMode(MOTOR, OUTPUT);
  digitalWrite(MOTOR, HIGH );   // Inverted control (HIGH = OFF)
 };

//Measure the current, display on LED and calculate and return the RMS value of the current over 100mSec
int SampleRMS(){
  unsigned long currentAcc = 0;
  unsigned int count = 0;
  unsigned long prevMicros = micros() - sampleInterval ;
  while (count < numSamples){
    if (micros() - prevMicros >= sampleInterval){
      int adc_raw = abs(analogRead(CurrentAnalogPin) - adc_zero);  // Since zero amp is at ~ half voltage 2.5V output of the ACS712 
      analogWrite(LED, adc_raw/4);                                 // Analog ammeter using the LED
      currentAcc += (unsigned long)(adc_raw * adc_raw);            // RMS calculation
      ++count;
      prevMicros += sampleInterval;}}
  float SampleRMS = sqrt((float)currentAcc/(float)numSamples);
return SampleRMS;}

//Now grinding
void grind(){
last_second = millis();
egg_counter = 0;
while (delayLeft > 0){ // If delayLeft > 0 means motor should be on
    digitalWrite(MOTOR, LOW); //Power motor on
    while(SampleRMS() * current_factor > THRESHOLD){// Factor output to read in mA      
      ++egg_counter;
      delayLeft = DELAY_OFF; 
      last_second = millis();}
    if (millis() - last_second >= 1000){ 
    last_second = millis();
     --delayLeft;}}
digitalWrite(MOTOR, HIGH);
analogWrite(LED, 0);}

//Drop eggs
void eggdrop(){
egg_counter = EGG_DROPS;
for(int i = 0; i < egg_counter; i++){
  delay(EGG_DROP_TIME);
  digitalWrite(MOTOR, LOW); //Power motor on
  while (SampleRMS() * current_factor > THRESHOLD) digitalWrite(MOTOR, LOW);
  analogWrite(LED, 0);
  digitalWrite(MOTOR, HIGH);}}         

// Interrupt Service Handler
void pin2_isr_grind(){delayLeft = DELAY_ON;}

void loop(){
// Main function here is sleep while waiting for switch... See  http://playground.arduino.cc/Learning/ArduinoSleepCode
noInterrupts();
sleep_enable();
power_all_disable ();   
set_sleep_mode(SLEEP_MODE_IDLE); 
attachInterrupt(0, pin2_isr_grind, FALLING);
interrupts();
sleep_cpu();
//Now sleeping...
sleep_disable();
power_all_enable ();   
grind();
if((egg_counter > 4) && (EGG_DROPS > 0)) eggdrop();} //drop Versalab eggs (leftover coffee)